Português (Brasil)

Traduzido por IA. Ainda não revisado pela comunidade. Ler em inglês

Blog · 13 de setembro de 2023 · Steve Simpson · Integração

JSON Jamboree: desserialização fixa contra dinâmica nos callouts Apex

Introdução:

Olá! Eu sou Steve Simpson, Salesforce Certified Technical Architect e instrutor. Neste post, vamos explorar diferentes técnicas para fazer o parsing de JSON em callouts Apex no Salesforce: parsing de JSON fixo, parsing de JSON dinâmico e uma abordagem híbrida que combina flexibilidade e facilidade de uso.

Seção 1: parsing de JSON fixo com desserialização em uma linha

Para estruturas JSON simples que não mudam com frequência, você pode criar uma classe Apex que corresponda exatamente à estrutura do JSON. Assim dá para desserializar a string JSON num array com uma única linha de código. É um método poderoso e eficiente para estruturas JSON estáticas.

Captura de tela: a documentação da API de chegadas de voos do OpenSky, com seus parâmetros de requisição Captura do Postman: uma chamada GET à API de chegadas do OpenSky retornando dados de voos em JSON

public class OS_FlightStatusModel
{
    public String icao24 {get;set;}
    public Integer firstSeen {get;set;}
    public String estDepartureAirport {get;set;}
    public Integer lastSeen {get;set;}
    public String estArrivalAirport {get;set;}
    public String callsign {get;set;}
    public Integer estDepartureAirportHorizDistance {get;set;}
    public Integer estDepartureAirportVertDistance {get;set;}
    public Integer estArrivalAirportHorizDistance {get;set;}
    public Integer estArrivalAirportVertDistance {get;set;}
    public Integer departureAirportCandidatesCount {get;set;}
    public Integer arrivalAirportCandidatesCount {get;set;}
    //---Use the JSON Deserialize
    public static List<OS_FlightStatusModel> parse(String json)
    {
        return (List<OS_FlightStatusModel>) System.JSON.deserialize(json, List<OS_FlightStatusModel>.class);
    }
}

Com a classe acima, você faz o parsing do JSON facilmente com uma única linha de código:

//---Get the Flight Request
 private static List<OS_FlightStatusModel> getFlightRequest(String requestURL)
 {
//---Return structure
List<OS_FlightStatusModel> retList = new List<OS_FlightStatusModel>();
//---Make the request
HttpResponse resp = getRequest( requestURL);
//---Check for Success
Integer respStatusCode = resp.getStatusCode();
if (respStatusCode == 200)
 {
//---Read the Payload
String payload = resp.getBody();
debug('Payload: ' + payload);
//---Parse the payload
retList = OS_FlightStatusModel.parse(payload);
if (retList != null)
 {
System.debug('Found ' + retList.size() + ' records');
for( OS_FlightStatusModel mRow : retList)
 {
debug('Row: ' + mRow);
 }
 }
 }
else
 {
//---Handle an error
debug('Response Status Code: ' + respStatusCode);
 }
return retList;
 }

Seção 2: parsing de JSON dinâmico

Para estruturas JSON mais complexas, como arrays ou objetos aninhados, você pode precisar do parsing dinâmico. Essa abordagem exige mais linhas de código e uma navegação cuidadosa pelos tokens do JSON. Pode parecer mais complicada, mas é necessária para estruturas JSON avançadas.

Exemplo:

/****************************************************************************************
* @Name OS_StateModelParser
* @Author Steve Simpson - steve@stevetecharc.com
* @Date 2023
*
* @Description Parser for reading State Models from JSON
****************************************************************************************
* Version Developer Date Description
*----------------------------------------------------------------------------------------
* 1.0 Steve Simpson 2023 Initial Creation
****************************************************************************************/
public with sharing class OS_StateModelParser extends OS_BaseParser
{
private OS_StateResponseModel responseModel {get; set;}
//--Parse the payload into the OS_StateResponseModel
public OS_StateResponseModel parse(String json)
 {
//---Setup the return value
responseModel = new OS_StateResponseModel();
responseModel.States = new List<OS_StateModel>();
try
 {
parseBody(json);
 }
catch (Exception ex)
 {
debug( 'Exception: ' + ex.getMessage() + ' ' + ex.getStackTraceString());
debugJSON(json);
 }
return responseModel;
 }
//---Parse the body of the JSON
private void parseBody(String json)
 {
//---Set the default Page Size
if (PageSize == 0) PageSize = DEFAULT_PAGE_SIZE;
Boolean hasTokenTime = false;
Boolean hasTokenStates = false;
JSONParser parser = System.JSON.createParser(json);
//---Read Token by Token
while (parser.nextToken() != System.JSONToken.END_OBJECT)
 {
//---Read the current Token, check its field name
if (parser.getCurrentToken() == System.JSONToken.FIELD_NAME)
 {
String text = parser.getText();
debug( 'Json Token: ' + text);
//---If the next token has a value, then write it, this handles null values
if (parser.nextToken() != System.JSONToken.VALUE_NULL)
 {
//---Read the time
if (text == 'time')
 {
responseModel.ResponseTime = parser.getIntegerValue();
hasTokenTime = true;
 }
//---Read the states
if (text == 'states')
 {
responseModel.States = parseStateList(parser);
hasTokenStates = true;
 }
 }
 }
//---If have both tags, then break out of loop
if (hasTokenStates && hasTokenTime) break;
 }
 }
//---Parse the States
private List<OS_StateModel> parseStateList(JSONParser parser)
 {
CurrentRecord = 0;
//---Build the return list
List<OS_StateModel> retList = new List<OS_StateModel>();
//---Go to the next token if needed
if (parser.getCurrentToken() == null) parser.nextToken();
//---Iterate over the items
while (parser.nextToken() != System.JSONToken.END_ARRAY)
 {
CurrentRecord++; //---Track the current record
String logLine = 'Rec: ' + CurrentRecord + ': ';
if (CurrentRecord > getMaxRecord())
 {
//---If past the max record, then break out of loop
debug(logLine + 'End of page');
break;
 }
else if (CurrentRecord >= getFirstRecordToProcess())
 {
//---Build a new State Row
OS_StateModel sModel = new OS_StateModel();
parseStateItem(parser, sModel);
retList.add(sModel);
debug(logLine + 'State: ' + sModel);
 }
else
 {
//---Pass in null model to trigger token advancement without reading values
parseStateItem(parser, null);
debug(logLine + 'Skipped');
 }
 }
return retList;
 }
//---Parse the States
private void parseStateItem(JSONParser parser, OS_StateModel sModel)
 {
//---Go to the next token if needed
if (parser.getCurrentToken() == null) parser.nextToken();
Integer position = 0;
while (parser.nextToken() != System.JSONToken.END_ARRAY)
 {
if (sModel != null && parser.getCurrentToken() != System.JSONToken.VALUE_NULL)
 {
if (position == 0) sModel.icao24 = parser.getText();
if (position == 1) sModel.callsign = parser.getText();
if (position == 2) sModel.origin_country = parser.getText();
if (position == 3) sModel.time_position = parser.getIntegerValue();
if (position == 4) sModel.last_contact = parser.getIntegerValue();
if (position == 5) sModel.longitude = parser.getDoubleValue();
if (position == 6) sModel.latitude = parser.getDoubleValue();
if (position == 7) sModel.baro_altitude = parser.getDoubleValue();
if (position == 8) sModel.on_ground = parser.getBooleanValue();
if (position == 9) sModel.velocity = parser.getDoubleValue();
if (position == 10) sModel.true_track = parser.getDoubleValue();
if (position == 11) sModel.vertical_rate = parser.getDoubleValue();
if (position == 12)
 {
//---Sensors, sub Array, should be null
 }
if (position == 13) sModel.geo_altitude = parser.getDoubleValue();
if (position == 14) sModel.squawk = parser.getText();
if (position == 15) sModel.spi = parser.getBooleanValue();
if (position == 16) sModel.position_source = parser.getIntegerValue();
if (position == 17) sModel.category = parser.getIntegerValue();
 }
position++;
//System.debug('Position ' + position);
 }
 }
}

Seção 3: mapeamento dinâmico com metadados personalizados

Se precisar de ainda mais flexibilidade, considere o mapeamento dinâmico com metadados personalizados. Essa abordagem permite mapear campos do JSON para campos de SObject dinamicamente, sem mudar o código. Com o mapeamento dinâmico, dá para adicionar ou remover campos na hora, o que traz muita flexibilidade em produção.

Exemplo:

Crie metadados personalizados que mapeiem os campos do JSON para nomes de API, posições e tipos de dados dos SObjects.

Carregue os metadados personalizados e use-os para atribuir valores dinamicamente aos campos dos SObjects.

/****************************************************************************************
* @Name OS_StateSObjectModelParser
* @Author Steve Simpson - steve@stevetecharc.com
* @Date 2023
*
* @Description Parser for reading State Models from JSON
****************************************************************************************
* Version Developer Date Description
*----------------------------------------------------------------------------------------
* 1.0 Steve Simpson 2023 Initial Creation
****************************************************************************************/
public with sharing class OS_StateSObjectModelParser extends OS_BaseParser
{
private OS_StateSObjectResponseModel responseModel {get; set;}
private List<OS_StateMap__mdt> mapList {get;set;}
//--Parse the payload into the OS_StateResponseModel
public OS_StateSObjectResponseModel parse(String json)
 {
mapList = OS_StateMap__mdt.getAll().values();
//---Setup the return value
responseModel = new OS_StateSObjectResponseModel();
responseModel.States = new List<OS_State__c>();
try
 {
parseBody(json);
 }
catch (Exception ex)
 {
debug( 'Exception: ' + ex.getMessage() + ' ' + ex.getStackTraceString());
debugJSON(json);
 }
return responseModel;
 }
//---Parse the body of the JSON
private void parseBody(String json)
 {
//---Set the default Page Size
if (PageSize == 0) PageSize = DEFAULT_PAGE_SIZE;
Boolean hasTokenTime = false;
Boolean hasTokenStates = false;
JSONParser parser = System.JSON.createParser(json);
//---Read Token by Token
while (parser.nextToken() != System.JSONToken.END_OBJECT)
 {
//---Read the current Token, check its field name
if (parser.getCurrentToken() == System.JSONToken.FIELD_NAME)
 {
String text = parser.getText();
debug( 'Json Token: ' + text);
//---If the next token has a value, then write it, this handles null values
if (parser.nextToken() != System.JSONToken.VALUE_NULL)
 {
//---Read the time
if (text == 'time')
 {
responseModel.ResponseTime = parser.getIntegerValue();
hasTokenTime = true;
 }
//---Read the states
if (text == 'states')
 {
responseModel.States = parseStateList(parser);
hasTokenStates = true;
 }
 }
 }
//---If have both tags, then break out of loop
if (hasTokenStates && hasTokenTime) break;
 }
 }
//---Parse the States
private List<OS_State__c> parseStateList(JSONParser parser)
 {
CurrentRecord = 0;
//---Build the return list
List<OS_State__c> retList = new List<OS_State__c>();
//---Go to the next token if needed
if (parser.getCurrentToken() == null) parser.nextToken();
//---Iterate over the items
while (parser.nextToken() != System.JSONToken.END_ARRAY)
 {
CurrentRecord++; //---Track the current record
String logLine = 'Rec: ' + CurrentRecord + ': ';
if (CurrentRecord > getMaxRecord())
 {
//---If past the max record, then break out of loop
debug(logLine + 'End of page');
break;
 }
else if (CurrentRecord >= getFirstRecordToProcess())
 {
//---Build a new State Row
OS_State__c osState = new OS_State__c();
parseStateItem(parser, osState);
retList.add(osState);
debug(logLine + 'State: ' + osState);
 }
else
 {
//---Pass in null model to trigger token advancement without reading values
parseStateItem(parser, null);
debug(logLine + 'Skipped');
 }
 }
return retList;
 }
//---Parse the States
private void parseStateItem(JSONParser parser, OS_State__c osState)
 {
//---Go to the next token if needed
if (parser.getCurrentToken() == null) parser.nextToken();
Integer position = 0;
while (parser.nextToken() != System.JSONToken.END_ARRAY)
 {
if (osState != null && parser.getCurrentToken() != System.JSONToken.VALUE_NULL)
 {
OS_StateMap__mdt curMap = null;
for(OS_StateMap__mdt mapRow : mapList)
 {
if (mapRow.Position__c == position)
 {
curMap = mapRow;
break;
 }
 }
if (curMap != null)
 {
String apiName = curMap.API_Name__c;
if (curMap.Data_Type__c == 'Text')
 {
osState.put(apiName, parser.getText());
 }
if (curMap.Data_Type__c == 'Integer')
 {
osState.put(apiName, parser.getIntegerValue());
 }
if (curMap.Data_Type__c == 'Double')
 {
osState.put(apiName, parser.getDoubleValue());
 }
if (curMap.Data_Type__c == 'Boolean')
 {
osState.put(apiName, parser.getBooleanValue());
 }
 }
 }
position++;
//System.debug('Position ' + position);
 }
 }
}

Conclusão:

Nos callouts Apex do Salesforce, você pode escolher entre várias técnicas de parsing de JSON conforme a necessidade. Para JSON simples e estático, use o parsing fixo com desserialização em uma linha. Para estruturas mais complexas, considere o parsing dinâmico. E para a máxima flexibilidade, use o mapeamento dinâmico com metadados personalizados. Cada abordagem tem seus casos de uso, então escolha a que melhor se encaixa no seu projeto.

Bom código!

Fique de olho

Para mais ideias e dicas, acompanhe aqui em www.SteveTechArc.com e no canal do YouTube @SteveTechArc (opens in a new tab). Inscreva-se e aprofunde seu entendimento do Salesforce e de como integrá-lo a outros sistemas.

Ajudando a mudar o mundo compartilhando conhecimento sobre integração com outros arquitetos e com quem está na jornada para se tornar um!

Transcrição feita com a ajuda de IA

STA 1.6